home *** CD-ROM | disk | FTP | other *** search
/ The Atari Compendium / The Atari Compendium (Toad Computers) (1994).iso / files / umich / falcon / programm.ing / nt_dsp1.lzh / NT_DSP1.MSA / FLOAT / FPSUB.ASM < prev   
Assembly Source File  |  1989-01-24  |  3KB  |  98 lines
  1.  
  2. ;
  3. ; This program originally available on the Motorola DSP bulletin board.
  4. ; It is provided under a DISCLAIMER OF WARRANTY available from
  5. ; Motorola DSP Operation, 6501 Wm. Cannon Drive W., Austin, Tx., 78735.
  6. ; 
  7. ; Last Update 15 Oct 87   Version 2.1
  8. ;
  9. fpsub   ident   2,1
  10. ;
  11. ; MOTOROLA DSP56000/1 FPLIB - VERSION 2
  12. ;
  13. ; FPSUB - FLOATING POINT SUBTRACTION SUBROUTINE
  14. ;
  15. ; Entry points: fsub_xa R = A - X
  16. ;               fsub_xy R = Y - X
  17. ;
  18. ;       m = 24 bit mantissa (two's complement, normalized fraction)
  19. ;
  20. ;       e = 14 bit exponent (unsigned integer, biased by +8191)
  21. ;
  22. ; Input variables:
  23. ;
  24. ;   X   x1 = mx  (normalized)
  25. ;       x0 = ex
  26. ;
  27. ;   Y   y1 = my  (normalized)
  28. ;       y0 = ey
  29. ;
  30. ;   A   a2 = sign extension of ma
  31. ;       a1 = ma  (normalized)
  32. ;       a0 = zero
  33. ;
  34. ;       b2 = sign extension of ea (always zero)
  35. ;       b1 = ea
  36. ;       b0 = zero
  37. ;
  38. ; Output variables:
  39. ;
  40. ;   R   a2 = sign extension of mr
  41. ;       a1 = mr  (normalized)
  42. ;       a0 = zero
  43. ;
  44. ;       b2 = sign extension of er (always zero)
  45. ;       b1 = er
  46. ;       b0 = zero
  47. ;
  48. ; Error conditions:     Set CCR L=1 if floating point overflow.  Result
  49. ;                       is set to the maximum floating point value of the
  50. ;                       correct sign.  The CCR L bit remains set until
  51. ;                       cleared by the user.
  52. ;
  53. ;                       Set CCR L=1 if floating point underflow.  Result
  54. ;                       is set to floating point zero.  The CCR L bit
  55. ;                       remains set until cleared by the user.
  56. ;
  57. ; Assumes n0, m0, shift constant table and scaling modes
  58. ; initialized by previous call to the subroutine "fpinit".
  59. ;
  60. ; Alters Data ALU Registers
  61. ;       a2      a1      a0      a
  62. ;       b2      b1      b0      b
  63. ;       x1      x0      y1      y0
  64. ;
  65. ; Alters Address Registers
  66. ;       r0
  67. ;
  68. ; Alters Program Control Registers
  69. ;       pc      sr                                                  
  70. ;
  71. ; Uses 0 locations on System Stack
  72. ;
  73. ;
  74. fsub_xy tfr     y0,b    y1,a            ;get ey, my
  75. fsub_xa sub     x0,b    b1,y1           ;compare delta = ea - ex, save ea
  76.         jge     _dpos                   ;jump if ea >= ex
  77. ;
  78. ; ea < ex
  79. ;
  80. _dneg   tfr     x1,a    a1,x1           ;swap ma with mx
  81.         neg     a       x0,y1           ;negate mx, save ex
  82.         abs     b       fp_space:fp_23,y0       ;negate er', get delta limit
  83.         cmp     y0,b    b1,r0           ;check delta limit, save delta
  84.         jle     addm                    ;jump if delta =< 23
  85.         tst     a       x0,r0           ;get er', setup CCR for norm
  86.         jmp     norm1                   ;normalize result
  87. ;
  88. ; ea >= ex
  89. ;
  90. _dpos   move            fp_space:fp_23,y0       ;get delta limit
  91.         cmp     y0,b    b1,r0           ;check delta limit, save delta
  92.         jgt     done1                   ;jump if delta > 23
  93.         move    fp_space:(r0+n0),x0     ;lookup shift constant s
  94.         mac     x1,x0,a y1,r0           ;denormalize by s, 
  95.                                         ;  subtract mantissa, get er'
  96.         jmp     norm                    ;normalize result
  97.  
  98.